Creating Objects

When you write code for an object oriented application you are creating components. When you run your application your components are used as "blueprints" to create objects.

So you can think of components as instructions on how to create many similar objects, which is similar to how blueprints for a house could be used to build many similar houses.

In the diagram we see one house blueprint on a piece of paper, which is used to create three lovely houses. We also see our object blueprint on a piece of paper (i.e. our component) which is used to create three separate objects.

Our component defines a private internal variable called name and a function getName(). Notice that this results in each of our objects having their own personal private name variable and getName() function.

Sometimes you may only need one object of a particular kind in your application, such as an object that knows how to authenticate users, and other times you may need more than one of a kind of object, such as having one object for every user currently logged into your system. Generally, however, components are used to create many objects.

Object creation

ColdFusion provides several techniques for creating objects including the <cfinvoke> tag, the <cfobject> tag and the createObject() function.

The cfinvoke tag

The <cfinvoke> tag is used to execute a function on a component. Let's look at a common example of how <cfinvoke> is used:

<cfinvoke
    component="Person"
    method="getName"
    returnVariable="myName">

This code does the following

1. creates a new object based on the Person.cfc component,
2. executes it's getName() function,
3. returns the name in a variable called myName, and finally
4. discards the object created in (1)

The main idea to note here is that the object is created and discarded in the one step.

There is a bit more to this tag but this is a good example of common usage.

The cfobject tag

The <cfobject> tag is different in that it is used to create objects and not discard them immediately.

<cfobject
    type="component"
    component="Person"
    name="myPerson">

This example takes the following steps

1. Creates a new object based on the Person.cfc component
2. Places a "reference" to that object in the myPerson variable.

A "reference" is essentially handle that lets you "hold onto" an object once it has been created. This reference can be given any name you like, such as "myPerson". Once you have a reference to an object you can then call whatever functions you need on that object.

So <cfobject> allows us to write code such as:

<!--- Create a new Person object and call it "myPerson" --->
<cfobject
    type="component"
    component="Person"
    name="myPerson">

<!--- Call some functions on myPerson --->
<cfset name = myPerson.getName()>
<cfset dob = myPerson.getDateOfBirth()>

As with <cfinvoke> there is much more to this tag than this simple example.

The createObject() function

The createObject() function is very similar to <cfobject> in that its purpose is to create objects and provide you with a reference to them for further use.

<cfset myPerson = createObject("component","Person")>

This is identical to the <cfobject> example above:

1. Creates a new object based on the Person.cfc component
2. Places a "reference" to that object in the myPerson variable.

And then using our object:

<!--- Create a new Person object and call it "myPerson" --->
<cfset myPerson = createObject("component","Person")>

<!--- Call some functions on myPerson --->
<cfset name = myPerson.getName()>
<cfset dob = myPerson.getDateOfBirth()>

Which syntax should you use?

The tag based techniques have particular uses, but typically you should use the createObject() function. For simple component usage the createObject() function can perform the behaviour of both the cfinvoke and cfobject tag.

cfinvoke: Executes functions on an object.

cfobject: Creates an object and returns a reference.

createObject: Creates an object and returns a reference and allows you to execute a function immediately on that object.

<!--- Create and initialise a Person object --->
<cfset myPerson = createObject("component","Person").init()>